利用VB捕捉并保存屏幕圖象

大家知道在VB下利用API函數Bitblt可以將屏幕或者窗口上的圖象拷貝到VB中的PictureBox對象中,但是如果簡單的利用PictureBox的SavePicture函數來保存圖象，會發現什么也保存不了。這篇文章就是介紹如何捕獲并利用Windows下的OLE API函數保存圖象。
　　首先來看源程序，首先建立一個新的工程文件，然后在Form1中加入5個CommandButton對象和一個PictureBox對象，然后在Form1中加入以下代碼：
Option Explicit
Option Base 0

Private Type PALETTEENTRY
　 peRed As Byte
　 peGreen As Byte
　 peBlue As Byte
　 peFlags As Byte
End Type

Private Type LOGPALETTE
　 palVersion As Integer
　 palNumEntries As Integer
　 palPalEntry(255) As PALETTEENTRY
End Type

Private Type GUID
　 Data1 As Long
　 Data2 As Integer
　 Data3 As Integer
　 Data4(7) As Byte
End Type

Private Const RASTERCAPS As Long = 38
Private Const RC_PALETTE As Long = &H100
Private Const SIZEPALETTE As Long = 104

Private Type RECT
　 Left As Long
　 Top As Long
　 Right As Long
　 Bottom As Long
End Type

Private Declare Function CreateCompatibleDC Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function CreateCompatibleBitmap Lib "GDI32" (ByVal hDC As Long, _
　　　　ByVal nWidth As Long, ByVal nHeight As Long) As Long
Private Declare Function GetDeviceCaps Lib "GDI32" (ByVal hDC As Long, ByVal _
　　　　iCapabilitiy As Long) As Long
Private Declare Function GetSystemPaletteEntries Lib "GDI32" (ByVal hDC As Long, _
　　　　ByVal wStartIndex As Long, ByVal wNumEntries As Long, lpPaletteEntries _
　　　　As PALETTEENTRY) As Long
Private Declare Function CreatePalette Lib "GDI32" (lpLogPalette As LOGPALETTE) _
　　　　As Long
Private Declare Function SelectObject Lib "GDI32" (ByVal hDC As Long, ByVal hObject _
　　　　As Long) As Long
Private Declare Function BitBlt Lib "GDI32" (ByVal hDCDest As Long, ByVal XDest As _
　　　　Long, ByVal YDest As Long, ByVal nWidth As Long, ByVal nHeight As Long, _
　　　　ByVal hDCSrc As Long, ByVal XSrc As Long, ByVal YSrc As Long, ByVal dwRop _
　　　　As Long) As Long
Private Declare Function DeleteDC Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function GetForegroundWindow Lib "USER32" () As Long
Private Declare Function SelectPalette Lib "GDI32" (ByVal hDC As Long, ByVal hPalette _
　　　　As Long, ByVal bForceBackground As Long) As Long
Private Declare Function RealizePalette Lib "GDI32" (ByVal hDC As Long) As Long
Private Declare Function GetWindowDC Lib "USER32" (ByVal hWnd As Long) As Long
Private Declare Function GetDC Lib "USER32" (ByVal hWnd As Long) As Long
Private Declare Function GetWindowRect Lib "USER32" (ByVal hWnd As Long, lpRect As _
　　　　RECT) As Long
Private Declare Function ReleaseDC Lib "USER32" (ByVal hWnd As Long, ByVal hDC As _
　　　　Long) As Long
Private Declare Function GetDesktopWindow Lib "USER32" () As Long

Private Type PicBmp
　 Size As Long
　 Type As Long
　 hBmp As Long
　 hPal As Long
　 Reserved As Long
End Type

Private Declare Function OleCreatePictureIndirect Lib "olepro32.dll" (PicDesc As _
　　　　PicBmp, RefIID As GUID, ByVal fPictureOwnsHandle As Long, IPic As IPicture) As Long

注釋：捕捉整個屏幕
Private Sub Command1_Click()
　 Set Picture1.Picture = CaptureScreen()
End Sub

注釋：在兩秒鐘后捕捉當前的活動窗口
Private Sub Command2_Click()
　　MsgBox "當你關閉這個對話框兩秒鐘之后程序會捕捉處于活動狀態的窗口."
　　注釋：等待兩秒鐘
　　Dim EndTime As Date
　　EndTime = DateAdd("s", 2, Now)
　　Do Until Now > EndTime
　　　 DoEvents
　　　 Loop
　　Set Picture1.Picture = CaptureActiveWindow()
　　
　　Me.SetFocus
End Sub

Private Sub Command3_Click()
　　Set Picture1.Picture = Nothing
End Sub

Public Function CreateBitmapPicture(ByVal hBmp As Long, ByVal hPal As Long) As Picture
　Dim r As Long

　 Dim Pic As PicBmp
　 Dim IPic As IPicture
　 Dim IID_IDispatch As GUID

　 注釋：填充IDispatch界面
　 With IID_IDispatch
　　　.Data1 = &H20400
　　　.Data4(0) = &HC0
　　　.Data4(7) = &H46
　 End With

　 注釋：填充Pic
　 With Pic
　　　.Size = Len(Pic)　　　　　注釋： Pic結構長度
　　　.Type = vbPicTypeBitmap　 注釋： 圖象類型
　　　.hBmp = hBmp　　　　　　　注釋： 位圖句柄
　　　.hPal = hPal　　　　　　　注釋： 調色板句柄
　 End With

　 注釋：建立Picture圖象
　 r = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)

　 注釋：返回Picture對象
　 Set CreateBitmapPicture = IPic
End Function

Public Function CaptureWindow(ByVal hWndSrc As Long, ByVal Client As Boolean, ByVal _
　　LeftSrc As Long, ByVal TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc _
　　As Long) As Picture

　　Dim hDCMemory As Long
　　Dim hBmp As Long
　　Dim hBmpPrev As Long
　　Dim r As Long
　　Dim hDCSrc As Long
　　Dim hPal As Long
　　Dim hPalPrev As Long
　　Dim RasterCapsScrn As Long
　　Dim HasPaletteScrn As Long
　　Dim PaletteSizeScrn As Long
　　Dim LogPal As LOGPALETTE

　　If Client Then
　　　　hDCSrc = GetDC(hWndSrc)
　　Else
　　　　hDCSrc = GetWindowDC(hWndSrc)
　　End If

　　hDCMemory = CreateCompatibleDC(hDCSrc)
　　hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
　　hBmpPrev = SelectObject(hDCMemory, hBmp)

　　注釋：獲得屏幕屬性
　　RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS)
　　HasPaletteScrn = RasterCapsScrn And RC_PALETTE
　　PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE)

　　注釋：如果屏幕對象有調色板則獲得屏幕調色板
　　If HasPaletteScrn And (PaletteSizeScrn = 256) Then
　　　　注釋：建立屏幕調色板的拷貝
　　　　LogPal.palVersion = &H300
　　　　LogPal.palNumEntries = 256
　　　　r = GetSystemPaletteEntries(hDCSrc, 0, 256, LogPal.palPalEntry(0))
　　　　hPal = CreatePalette(LogPal)
　　　　注釋：將新建立的調色板選如建立的內存繪圖句柄中
　　　　hPalPrev = SelectPalette(hDCMemory, hPal, 0)
　　　　r = RealizePalette(hDCMemory)
　　End If

　　注釋：拷貝圖象
　　r = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, LeftSrc, TopSrc, vbSrcCopy)

　　hBmp = SelectObject(hDCMemory, hBmpPrev)

　　If HasPaletteScrn And (PaletteSizeScrn = 256) Then
　　　　hPal = SelectPalette(hDCMemory, hPalPrev, 0)
　　End If

　　注釋：釋放資源
　　r = DeleteDC(hDCMemory)
　　r = ReleaseDC(hWndSrc, hDCSrc)

　　Set CaptureWindow = CreateBitmapPicture(hBmp, hPal)
End Function
注釋：capturescreen函數捕捉整個屏幕圖象
Public Function CaptureScreen() As Picture
　　Dim hWndScreen As Long

　　注釋：獲得桌面的窗口句柄
　　hWndScreen = GetDesktopWindow()
　　Set CaptureScreen = CaptureWindow(hWndScreen, False, 0, 0, Screen.Width _
　　　　\ Screen.TwipsPerPixelX, Screen.Height \ Screen.TwipsPerPixelY)
End Function

Public Function CaptureActiveWindow() As Picture
　　Dim hWndActive As Long
　　Dim r As Long
　　Dim RectActive As RECT
　　
　　hWndActive = GetForegroundWindow()
　　r = GetWindowRect(hWndActive, RectActive)
　　Set CaptureActiveWindow = CaptureWindow(hWndActive, False, 0, 0, _
　　　　RectActive.Right - RectActive.Left, RectActive.Bottom - RectActive.Top)
End Function

Public Sub PrintPictureToFitPage(Prn As Printer, Pic As Picture)
　　Const vbHiMetric As Integer = 8
　　Dim PicRatio As Double
　　Dim PrnWidth As Double
　　Dim PrnHeight As Double
　　Dim PrnRatio As Double
　　Dim PrnPicWidth As Double
　　Dim PrnPicHeight As Double
　　
　　If Pic.Height >= Pic.Width Then
　　　　Prn.Orientation = vbPRORPortrait
　　Else
　　　　Prn.Orientation = vbPRORLandscape
　　End If
　　
　　PicRatio = Pic.Width / Pic.Height
　　
　　PrnWidth = Prn.ScaleX(Prn.ScaleWidth, Prn.ScaleMode, vbHiMetric)
　　PrnHeight = Prn.ScaleY(Prn.ScaleHeight, Prn.ScaleMode, vbHiMetric)
　　PrnRatio = PrnWidth / PrnHeight
　　
　　If PicRatio >= PrnRatio Then
　　　　PrnPicWidth = Prn.ScaleX(PrnWidth, vbHiMetric, Prn.ScaleMode)
　　　　PrnPicHeight = Prn.ScaleY(PrnWidth / PicRatio, vbHiMetric, Prn.ScaleMode)
　　Else
　　　　PrnPicHeight = Prn.ScaleY(PrnHeight, vbHiMetric, Prn.ScaleMode)
　　　　PrnPicWidth = Prn.ScaleX(PrnHeight * PicRatio, vbHiMetric, Prn.ScaleMode)
　　End If
　　
　　Prn.PaintPicture Pic, 0, 0, PrnPicWidth, PrnPicHeight
End Sub

Private Sub Command4_Click()
　　CommonDialog1.DefaultExt = ".BMP"
　　CommonDialog1.Filter = "Bitmap Image (*.bmp)|*.bmp"
　　CommonDialog1.ShowSave
　　If CommonDialog1.FileName <> "" Then
　　　　SavePicture Picture1.Picture, CommonDialog1.FileName
　　End If
End Sub

Private Sub Command5_Click()
　　PrintPictureToFitPage Printer, Picture1.Picture
　　Printer.EndDoc
End Sub

Private Sub Form_Load()
　　Command1.Caption = "捕捉整個屏幕"
　　Command2.Caption = "兩秒鐘后捕捉活動窗口"
　　Command3.Caption = "清除圖象"
　　Command4.Caption = "保存圖象"
　　Command5.Caption = "打印圖象"
End Sub

　　運行程序，點擊command1或者Command2就可以捕捉成個屏幕或者窗口到Picture1中，然后點擊Command4或者Command5就可以保存或打印圖象。
　　上面的程序中最重要的是CaptureWindow函數以及CreateBitmapPicture函數，CaptureWindow函數建立與要捕捉的窗口的繪圖設備（Device Context）句柄相兼容的繪圖設備（Device Context）句柄，然后建立相應的調色板，最后將繪圖設備（Device Context）中的圖象拷貝到一個hBitmap對象句柄中。CreateBitmapPicture函數則根據傳遞過來的hBitmap對象句柄和調色板句柄建立一個Picture對象。在將這個對象賦予PictureBox的Picture屬性，然后就可以使用SavePicture函數來保存圖象了。
　　OleCreatePictureIndirect函數支持的不僅有BMP圖象，同時也支持Ico圖標，所以利用該函數和ExtractIcon函數也可以提取并保存Windows文件中的圖標。有興趣的讀者可以到我的主頁http://www.nease.net/~blackcat上下載源程序。

原文轉自：http://www.anti-gravitydesign.com