用VB5創建B/S程序

發表于:2007-07-14來源:作者:點擊數: 標簽:
隨著Windows 95中文版和Windows NT Server 4.0中文版的流行, Microsoft公司推出了相應平臺上的 開發 軟件: Visual Basic 5.0 中文企業 版。它為Windows環境下的 網絡 開發提供了強大的工具,Winsock控件就是其中之一。 Winsock控件建立在TCP、UDP協議的基礎
隨著Windows 95中文版和Windows NT Server 4.0中文版的流行, Microsoft公司推出了相應平臺上的開發軟件: Visual Basic 5.0 中文企業 版。它為Windows環境下的網絡開發提供了強大的工具,Winsock控件就是其中之一。
  Winsock控件建立在TCP、UDP協議的基礎上,完成與遠程計算機的通信。即使對TCP/IP不太熟悉的用戶,使用該控件也可以在十幾分鐘內創建一個簡單的客戶機/服務器程序。下面我們對Winsock控件的事件、方法、屬性按其在程序中出現的順序分別作詳細的介紹,以便更好地理解程序源代碼。
  服務器程序的實現過程是:
 ?。?)服務器程序必須設置好LocalPort屬性,作為偵聽端口,該值為一個整數(只要是一個其它TCP/IP應用程序沒有使用過的值即可)。
 ?。?)使用Listen方法進入偵聽狀態,等待客戶機程序的連接請求。
 ?。?)客戶機程序發出連接請求,使服務器程序產生ConnectionRequest事件,該事件得到一個參數requestID。
 ?。?)服務器程序用Aclearcase/" target="_blank" >ccept方法接受客戶機程序的requestID請求。這樣,服務器程序就可以用SendData方法發送數據了。Accept方法必須用上一步得到的requestID作為其參數。
 ?。?)當服務器程序接收到數據時,產生DataArrival事件,參數BytesTotal包含接收到的數據字節數。在該事件中,可以用GetData方法接收數據。
 ?。?)如果接受到Close事件,則用Close方法關閉TCP/IP連接。
  客戶機程序的實現過程是:
 ?。?) 客戶程序設置Remotehost屬性,以便指定運行服務器程序的主機 名,該字符串可在“控制面板|網絡|標識|計算機名”中查到。
 ?。?) 設置RemotePort屬性,以便指定服務器程序的偵聽端口。
 ?。?)使用Connect方法,向服務器提出連接請求。
 ?。?)服務器接受客戶機程序的請求,客戶機程序產生Connect事件,就可以用SendData方法發送數據了。
 ?。?)當客戶機程序接收到數據時,產生DataArrival事件,參數BytesTotal包含接收到的數據字節數。在該事件中,可以用GetData方法接收數據。
 ?。?)如果接受到Close事件,則用Close方法關閉連接。
  Winsock控件還有兩個重要的屬性,即Protocol和State。Protocol設定使用的協議是TCP還是UDP:取值sckTCPProtocol表示TCP, 取值sckUDPProtocol則表示UDP。因為Winsock控件的缺省設置是sckTCPProtocol,所以程序中并沒有使用Protocol屬性。State屬性反映的是當前TCP/IP的連接狀態,取值如表1所示。
  表1 Winsock控件的State屬性及其描述
常數 值 描述
sckClosed 0 缺省值,關閉。
SckOpen 1 打開。
SckListening 2 偵聽
sckConnectionPending 3 連接掛起
sckResolvingHost 4 識別主機。
sckHostResolved 5 已識別主機
sckConnecting 6 正在連接。
sckConnected 7 已連接。
sckClosing 8 同級人員正在關閉連接。
sckError 9    錯誤。
  先在一臺計算機上運行服務器程序,此時窗口上只有一個“退出”按鈕。 再在另一臺計算機上運行客戶機程序,在“連接”按鈕右邊的文本框中輸入服務器 的主機名后單擊“連接”按鈕。如果連接成功,則服務器和客戶機程序窗口都會出現兩個文本框。這時,兩端都可以在上面的文本框中輸入文字,這些文字會立即在下面的文本框中出現。
  服務器程序使用的控件如下:
 ?。?)Command1:退出按鈕;
 ?。?)textsend:發送數據文本框;
 ?。?)Winsockserver: 服務器Winsock;
 ?。?)textget :接收數據文本框。
  服務器程序的界面如圖所示。
  服務器程序的源代碼如下:
  Private Sub Command1_Click()
   End
  End Sub
  
  Private Sub Form_Load()
   textsend.Visible = False
   textget.Visible = False
   Winsockserver.LocalPort = 1001
   Winsockserver.Listen
  End Sub
  
  Private Sub textsend_Change()
   Winsockserver.SendData textsend.Text
  End Sub
  
  Private Sub Winsockserver_Close()
   Winsockserver.Close
   End
  End Sub
  
  Private Sub Winsockserver_ConnectionRequest(ByVal requestID As Long)
   textsend.Visible = True
   textget.Visible = True
   If Winsockserver.State <> sckClosed Then Winsockserver.Close
   Winsockserver.Accept requestID
  End Sub
  
  Private Sub Winsockserver_DataArrival(ByVal bytesTotal As Long)
   Dim tmpstr As String
   Winsockserver.GetData tmpstr
   textget.Text = tmpstr
  End Sub
  客戶機程序使用的控件如下:
 ?。?)Command1:退出按鈕;
 ?。?)Command2:連接按鈕;
 ?。?)Winsockclient:客戶Winsock;
 ?。?)Text1:主機名文本框;
 ?。?)Textsend:發送數據文本框;
 ?。?)Textget:接收數據文本框;   客戶機程序的界面如圖所示。
  客戶機程序的源代碼如下:
  Private Sub Command1_Click()
   End
  End Sub
  
  Private Sub Command2_Click()
   Winsockclient.Connect
  End Sub
  
  Private Sub Form_Load()
   textsend.Visible = False
   textget.Visible = False
   Winsockclient.RemotePort = 1001
   Winsockclient.RemoteHost = "sccdsz"
  End Sub
  
  Private Sub Text1_Change()
   Winsockclient.RemoteHost = Text1.Text
  End Sub
  
  Private Sub textsend_Change()
   Winsockclient.SendData textsend.Text
  End Sub
  
  Private Sub Winsockclient_Close()
   Winsockclient.Close
   End
  End Sub
  
  Private Sub winsockclient_Connect()
   textsend.Visible = True
   textget.Visible = True
   Command2.Visible = False
  End Sub
  
  Private Sub winsockclient_DataArrival(ByVal bytesTotal As Long)
   Dim tmpstr As String
   Winsockclient.GetData tmpstr
   textget.Text = tmpstr
  End Sub

原文轉自:http://www.anti-gravitydesign.com

国产97人人超碰caoprom_尤物国产在线一区手机播放_精品国产一区二区三_色天使久久综合给合久久97